欢迎来到Doc100.Net免费学习资源知识分享平台!
您的位置:首页 > 程序异常 >

vbs有没有办法给iis添加站点?解决办法

更新时间: 2014-01-05 01:53:05 责任编辑: Author_N1

 

VBS有没有办法给IIS添加站点?
在win2003的系统下,VBS能否给IIS6.0创建站点呢?

望高手赐教代码。

--参考方法--
VBScript code

' 其中全部大写的变量可自定义为常数

Function createSite()
    'On Error Resume Next

    Dim iNo
    Dim oW3SVC, oNewServer, oRoot

    createSite = False
    iNo = 1
    showMsg "获取站点标识..."
    Do While True
        Set oW3SVC = GetObject("IIS://LocalHost/W3SVC/" & iNo)
        If Err.Number = 0 Then
            iNo = iNo + 1
        Else
            Err.Clear
            Exit Do
        End If
    Loop
    Set oW3SVC = GetObject("IIS://LocalHost/W3SVC")
    If Err.Number<>0 Then
        MsgBox "Error: " & Err.Description
        Exit Function
    End If
    showMsg "创建站点" & SITE_NAME & "..."
    Set oNewServer = oW3SVC.Create("IIsWebServer", iNo)
    If Err.Number<>0 Then
        MsgBox "Error: " & Err.Description
        Exit Function
    End If
    showMsg "设置站点描述..."
    oNewServer.ServerComment = SITE_NAME
    showMsg "绑定站点IP,端口,主机头..."
    oNewServer.ServerBindings = Array(SITE_IP & ":" & SITE_PORT & ":" & SITE_HOST)
    Set oRoot = oNewServer.Create("IIsWebVirtualDir","Root")
    With oRoot
    showMsg "设置物理路径..."
        .Path = PRJ_PATH & "web\"
    showMsg "设置允许读取..."
        .AccessRead = True
    showMsg "设置不允许写入..."
        .AccessWrite = False
    showMsg "设置允许脚本访问资源..."
        .AccessSource = True
    showMsg "设置不允许浏览目录..."
        .EnableDirBrowsing = False
    showMsg "设置允许默认文档..."
        .EnableDefaultDoc = True
    showMsg "设置允许脚本访问..."
        .AccessScript = True
    showMsg "设置不记录日志..."
        .DontLog = True
    showMsg "设置不索引内容..."
        .ContentIndexed = False
    showMsg "设置允许Session..."
        .AspAllowSessionState = True
    showMsg "设置允许缓存..."
        .AspBufferingOn = True
    showMsg "创建应用程序..."
        .AppCreate2 2
    showMsg "设置应用程序名称..."
        .AppFriendlyName = "默认应用程序"
    showMsg "设置session超时时间..."
        .AspSessionTimeout = 10
    showMsg "设置不允许父路径..."
        .AspEnableParentPaths = False
        .SetInfo
    End With
    showMsg "保存设置项数据..."
    oNewServer.SetInfo
    oW3SVC.SetInfo
    If Err.Number<>0 Then
        MsgBox "Error: " & Err.Description
        Exit Function
    End If
    Set oW3SVC = Nothing
    Set oNewServer = Nothing
    Set oRoot = Nothing
    showMsg "创建站点完毕。"
    createSite = True
End Function 			
			
		
上一篇:上一篇
下一篇:下一篇

 

随机推荐程序问答结果

 

 

如对文章有任何疑问请提交到问题反馈,或者您对内容不满意,请您反馈给我们DOC100.NET论坛发贴求解。
DOC100.NET资源网,机器学习分类整理更新日期::2014-01-05 01:53:05
如需转载,请注明文章出处和来源网址:http://www.doc100.net/bugs/t/2527/
本文WWW.DOC100.NET DOC100.NET版权所有。