欢迎来到Doc100.Net免费学习资源知识分享平台!
您的位置:首页 > 程序异常 >

vbs获取指定文件夹内所有文件列表解决方法

更新时间: 2014-01-05 01:53:09 责任编辑: Author_N1

 

VBS获取指定文件夹内所有文件列表
VBS获取指定文件夹根目录所有文件和根目录所有文件夹列表(多级的文件夹不要),并循环输出。

--参考方法--
VBScript code

str = "e:\script\vbs"
ListFolder1 str
ListFolder2 str
ListFolder3 str

Sub ListFolder1(strFolder)

    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Set oFolder = oFSO.GetFolder(strFolder)
    strOut = strOut & "文件夹:" & vbCrLf
    For Each x In oFolder.SubFolders
        strOut = strOut & x.Name & vbCrLf
    Next
    strOut = strOut &  "文件:" & vbCrLf
    For Each x In oFolder.Files
        strOut = strOut &  x.Name & vbCrLf
    Next
    WScript.Echo strOut
    
End Sub

Sub ListFolder2(strFolder)
    '不能处理隐藏文件
    Set oShell = CreateObject("Shell.Application")
    Set oFolder = oShell.NameSpace(strFolder)
    For Each x In oFolder.Items
        strOut = strOut & x.Type & vbTab & x.Path & vbCrLf
    Next
    WScript.Echo strOut
    
End Sub

Sub ListFolder3(strFolder)

    Set oWMI = GetObject("Winmgmts:")
    For Each x In oWMI.ExecQuery("ASSOCIATORS OF {Win32_Directory.Name='"& strFolder &"'}" & "where ResultClass = CIM_logicalfile")
        strOut = strOut &  x.Name & vbCrLf
    Next
    WScript.Echo strOut

End Sub 			
			
		
上一篇:上一篇
下一篇:下一篇

 

随机推荐程序问答结果

 

 

如对文章有任何疑问请提交到问题反馈,或者您对内容不满意,请您反馈给我们DOC100.NET论坛发贴求解。
DOC100.NET资源网,机器学习分类整理更新日期::2014-01-05 01:53:09
如需转载,请注明文章出处和来源网址:http://www.doc100.net/bugs/t/2555/
本文WWW.DOC100.NET DOC100.NET版权所有。